This didn't seem to make much sense to me, if an approval is rejected, it is likely that the requesting user will want to know why this is the case. I was surprised to find that there was no setup option to configure the process this way.
I found that it is possible to make comments mandatory through adding a custom field, some extra steps to your approval process, and an apex trigger for the object. Here is a step by step guide if you want to do the same:
1) Create a new picklist custom field for your object. Set the label as "Approval Status". Add three picklist values ("Pending", "Approved" & "Rejected"). Make this field visible and editable by System Administrators only.
2) Navigate to the field updates menu (Setup --> App Setup --> Create --> Workflows & Approvals --> Field Updates) and create a new field update worfkflow action. Set the name of the new action to "Approval Status Pending" and unique name to "Approval_Status_Pending" and object to the object you added the custom field to. Then select the Approval Status field from the resulting drop down. In the new field value options, select "A specific value" then pick "Pending" status.
3) Repeat step 2 for the "Approved" and "Rejected" picklist values, creating field updates called "Approval Status Approved" and "Approval Status Rejected" respectively.
4) Navigate to your approval process. In "Initial Submission Actions" add the "Approval Status Pending" field update action. Add "Approval Status Approval" update to "Final Approval Actions" and "Approval Status Rejection" to "Final Rejection Actions".
5) Create a new "RequireRejectionComment" before update Apex trigger on your object with the following body (substituting "Invoice_Statement__c" for your object API name).
trigger RequireRejectionComment on Invoice_Statement__c (before update)
{
Map<Id, Invoice_Statement__c> rejectedStatements
= new Map<Id, Invoice_Statement__c>{};
for(Invoice_Statement__c inv: trigger.new)
{
/*
Get the old object record, and check if the approval status
field has been updated to rejected. If so, put it in a map
so we only have to use 1 SOQL query to do all checks.
*/
Invoice_Statement__c oldInv = System.Trigger.oldMap.get(inv.Id);
if (oldInv.Approval_Status__c != 'Rejected'
&& inv.Approval_Status__c == 'Rejected')
{
rejectedStatements.put(inv.Id, inv);
}
}
if (!rejectedStatements.isEmpty())
{
// UPDATE 2/1/2014: Get the most recent approval process instance for the object.
// If there are some approvals to be reviewed for approval, then
// get the most recent process instance for each object.
List<Id> processInstanceIds = new List<Id>{};
for (Invoice_Statement__c invs : [SELECT (SELECT ID
FROM ProcessInstances
ORDER BY CreatedDate DESC
LIMIT 1)
FROM Invoice_Statement__c
WHERE ID IN :rejectedStatements.keySet()])
{
processInstanceIds.add(invs.ProcessInstances[0].Id);
}
// Now that we have the most recent process instances, we can check
// the most recent process steps for comments.
for (ProcessInstance pi : [SELECT TargetObjectId,
(SELECT Id, StepStatus, Comments
FROM Steps
ORDER BY CreatedDate DESC
LIMIT 1 )
FROM ProcessInstance
WHERE Id IN :processInstanceIds
ORDER BY CreatedDate DESC])
{
if ((pi.Steps[0].Comments == null ||
pi.Steps[0].Comments.trim().length() == 0))
{
rejectedStatements.get(pi.TargetObjectId).addError(
'Operation Cancelled: Please provide a rejection reason!');
}
}
}
}
The trigger captures any update where the approval status is changed to "rejected" from another value. The field should have this value if it gets rejected, thanks to the way we set up the approval process.
If the field has been updated in this way, a SOQL query is used to analyse the last created rejection approval history object related to the trigger object. If the comment is empty, the update gets stopped, and an error message is added to the screen.
Here are some screen shots of rejecting a request in chatter, and the resulting error message:
Here are some screen shots of rejecting a request in chatter, and the resulting error message:
So there you have it, now all your rejections must have a comment, otherwise the operation is reversed! Because the rejection logic is handled in a trigger, this approach works for rejections through the standard pages, in chatter, and in Apex code.
Update 30/12/2013 : here is a sample test method for the trigger, hope it helps, remember to adapt it for your own implementation
/*
A sample test class for the Require Rejection Comment trigger
*/
@isTest
public class RequireRejectionCommentTest
{
/*
For this first test, create an object for approval, then
simulate rejeting the approval with an added comment for explanation.
The rejection should be processed normally without being interrupted.
*/
private static testmethod void testRejectionWithComment()
{
// Generate sample work item using utility method.
Id testWorkItemId = generateAndSubmitObject();
// Reject the submitted request, providing a comment.
Approval.ProcessWorkitemRequest testRej = new Approval.ProcessWorkitemRequest();
testRej.setComments('Rejecting request with a comment.');
testRej.setAction ('Reject');
testRej.setWorkitemId(testWorkItemId);
Test.startTest();
// Process the rejection
Approval.ProcessResult testRejResult = Approval.process(testRej);
Test.stopTest();
// Verify the rejection results
System.assert(testRejResult.isSuccess(), 'Rejections that include comments should be permitted');
System.assertEquals('Rejected', testRejResult.getInstanceStatus(),
'Rejections that include comments should be successful and instance status should be Rejected');
}
/*
For this test, create an object for approval, then reject the request, mark the approval status as pending, then
without a comment explaining why. The rejection should be halted, and
and an apex page message should be provided to the user.
*/
private static testmethod void testRejectionWithoutComment()
{
// Generate sample work item using utility method.
Id testWorkItemId = generateAndSubmitObject();
// Reject the submitted request, without providing a comment.
Approval.ProcessWorkitemRequest testRej = new Approval.ProcessWorkitemRequest();
testRej.setComments('');
testRej.setAction ('Reject');
testRej.setWorkitemId(testWorkItemId);
Test.startTest();
// Attempt to process the rejection
try
{
Approval.ProcessResult testRejResult = Approval.process(testRej);
system.assert(false, 'A rejection with no comment should cause an exception');
}
catch(DMLException e)
{
system.assertEquals('Operation Cancelled: Please provide a rejection reason!',
e.getDmlMessage(0),
'error message should be Operation Cancelled: Please provide a rejection reason!');
}
Test.stopTest();
}
/*
When an approval is approved instead of rejected, a comment is not required,
mark the approval status as pending, then ensure that this functionality still holds together.
*/
private static testmethod void testApprovalWithoutComment()
{
// Generate sample work item using utility method.
Id testWorkItemId = generateAndSubmitObject();
// approve the submitted request, without providing a comment.
Approval.ProcessWorkitemRequest testApp = new Approval.ProcessWorkitemRequest();
testApp.setComments ('');
testApp.setAction ('Approve');
testApp.setWorkitemId(testWorkItemId);
Test.startTest();
// Process the approval
Approval.ProcessResult testAppResult = Approval.process(testApp);
Test.stopTest();
// Verify the approval results
System.assert(testAppResult.isSuccess(),
'Approvals that do not include comments should still be permitted');
System.assertEquals('Approved', testAppResult.getInstanceStatus(),
'All approvals should be successful and result in an instance status of Approved');
}
/*
Put many objects through the approval process, some rejected, some approved,
some with comments, some without. Only rejctions without comments should be
prevented from being saved.
*/
private static testmethod void testBatchRejctions()
{
List<Invoice_Statement__c> testBatchIS = new List<Invoice_Statement__c>{};
for (Integer i = 0; i < 200; i++)
{
testBatchIS.add(new Invoice_Statement__c());
}
insert testBatchIS;
List<Approval.ProcessSubmitRequest> testReqs =
new List<Approval.ProcessSubmitRequest>{};
for(Invoice_Statement__c testinv : testBatchIS)
{
Approval.ProcessSubmitRequest testReq = new Approval.ProcessSubmitRequest();
testReq.setObjectId(testinv.Id);
testReqs.add(testReq);
}
List<Approval.ProcessResult> reqResults = Approval.process(testReqs);
for (Approval.ProcessResult reqResult : reqResults)
{
System.assert(reqResult.isSuccess(),
'Unable to submit new batch invoice statement record for approval');
}
List<Approval.ProcessWorkitemRequest> testAppRejs
= new List<Approval.ProcessWorkitemRequest>{};
for (Integer i = 0; i < 50 ; i++)
{
Approval.ProcessWorkitemRequest testRejWithComment = new Approval.ProcessWorkitemRequest();
testRejWithComment.setComments ('Rejecting request with a comment.');
testRejWithComment.setAction ('Reject');
testRejWithComment.setWorkitemId(reqResults[i*4].getNewWorkitemIds()[0]);
testAppRejs.add(testRejWithComment);
Approval.ProcessWorkitemRequest testRejWithoutComment = new Approval.ProcessWorkitemRequest();
testRejWithoutComment.setAction ('Reject');
testRejWithoutComment.setWorkitemId(reqResults[(i*4)+1].getNewWorkitemIds()[0]);
testAppRejs.add(testRejWithoutComment);
Approval.ProcessWorkitemRequest testAppWithComment = new Approval.ProcessWorkitemRequest();
testAppWithComment.setComments ('Approving request with a comment.');
testAppWithComment.setAction ('Approve');
testAppWithComment.setWorkitemId(reqResults[(i*4)+2].getNewWorkitemIds()[0]);
testAppRejs.add(testAppWithComment);
Approval.ProcessWorkitemRequest testAppWithoutComment = new Approval.ProcessWorkitemRequest();
testAppWithoutComment.setAction ('Approve');
testAppWithoutComment.setWorkitemId(reqResults[(i*4)+3].getNewWorkitemIds()[0]);
testAppRejs.add(testAppWithoutComment);
}
Test.startTest();
// Process the approvals and rejections
try
{
List<Approval.ProcessResult> testAppRejResults = Approval.process(testAppRejs);
system.assert(false, 'Any rejections without comments should cause an exception');
}
catch(DMLException e)
{
system.assertEquals(50, e.getNumDml());
for(Integer i = 0; i < 50 ; i++)
{
system.assertEquals((i*4) + 1, e.getDmlIndex(i));
system.assertEquals('Operation Cancelled: Please provide a rejection reason!',
e.getDmlMessage(i));
}
}
Test.stopTest();
}
/*
Utility method for creating single object, and submitting for approval.
The method should return the Id of the work item generated as a result of the submission.
*/
private static Id generateAndSubmitObject()
{
// Create a sample invoice statement object and then submit it for approval.
Invoice_Statement__c testIS = new Invoice_Statement__c();
insert testIS;
Approval.ProcessSubmitRequest testReq = new Approval.ProcessSubmitRequest();
testReq.setObjectId(testIS.Id);
Approval.ProcessResult reqResult = Approval.process(testReq);
System.assert(reqResult.isSuccess(),'Unable to submit new invoice statement record for approval');
return reqResult.getNewWorkitemIds()[0];
}
}